Créer un tableau de statistiques dans un état Access

Elle permet d'enregistrer les informations concernant les articles.

On garde uniquement les champs nécessaires pour notre base exemple.

Elle contient les informations des commandes clients.

On garde uniquement les champs importants.

Elle permet d'enregistrer le détail de chaque commande.

Là encore, on conserve uniquement les champs importants.

Elle relie les table T_Commande et T_DetailCommande sur le champ IdCommande et sélectionne les commandes comprises dans la période choisie sur le formulaire F_TableauStats.

Le champ calculé TotalLigne donne le montant total en fonction de la quantité d'articles commandée et de son prix unitaire :

TotalLigne: QteCommande*PrixUnitaire

La formule du champ IndMois donne l'indice du mois en fonction de la date de la commande et de la période choisie sur le formulaire F_TableauStats :

IndMois: DiffDate("m";SérieDate([Forms]![F_TableauStats]![CmbAnnee];[Forms]![F_TableauStats]![CmbMois];1);[DateCommande])+1

Cette requête analyse croisée affiche le tableau avec en en-têtes de ligne les articles, en en-têtes de colonne les mois de la période choisie, et à l'intersection la somme des montants des articles pour chacun des mois :

Le champ IndMois, placé en en-tête de colonne, donne l'indice du mois par rapport au 1er mois de la période choisie, il doit être compris entre 1 et 12. On va donc afficher uniquement les colonnes d'indices compris entre 1 et 12 :

Exemple d'affichage de la requête analyse croisée :

Il est en mode continu et à comme source de données la requête analyse croisée R_TableauStats, vue précédemment.

Il comporte les éléments suivants :

• Dans l'en-tête de formulaire, 12 étiquettes pour afficher les 12 mois de la période choisie ;
• Dans le détail, la référence et la désignation de l'article ;
• Toujours dans le détail, 12 zones de texte affichant les montants enregistrés pour chaque mois.

Ce sous-formulaire doit être intégré au formulaire principal F_TableauStats.

Positionnées dans l'en-tête du formulaire, elles permettent d'afficher les 12 mois de la période choisie.

Placées dans le détail du formulaire, elles affichent la référence et la désignation de chaque article.

Disposées dans le détail du formulaire, elles affichent les montants des articles pour chaque mois de la période choisie.

Il contient, en plus du sous-formulaire, des listes déroulantes pour choisir 1er mois de la période, et des boutons de commandes pour se déplacer dans le temps.

V-B-1. Procédure MajTableauStats▲

Private Sub MajTableauStats()
    ' Met à jour les en-têtes des 12 colonnes pour les 12 mois
    Dim i As Long, dt As Date
    
    dt = DateSerial(Me.cmbAnnee, Me.CmbMois, 1) ' date du 1er jour du mois sélectionné
    
    For i = 1 To 12 ' on parcourt les 12 étiquettes pour les 12 en-têtes de colonne
        ' on copie dans l'en-tête de la colonne d'indice i du sous-formulaire le mois correspondant à la date dt au format du type "0ct 19"
        Me.SF_TableauStats.Form("lblCol" & i).Caption = Format(dt, "mmm yy")
        dt = DateAdd("m", 1, dt) ' on passe au mois suivant
    Next i
    
    Me.SF_TableauStats.Requery ' on rafraîchit le sous*formulaire SF_TableauStats
    
End Sub

V-B-2. Bouton de commande CmdImprimer▲

Private Sub CmdImprimer_Click()
On Error GoTo Err_CmdImprimer_Click

    Dim stDocName As String

    stDocName = "E_TableauStats"
    DoCmd.OpenReport stDocName, acPreview ' ouvre l'état E_TableauStats en mode aperçu avant impression

Exit_CmdImprimer_Click:
    Exit Sub

Err_CmdImprimer_Click:
    MsgBox Err.Description
    Resume Exit_CmdImprimer_Click
    
End Sub

V-B-3. Liste déroulante cmbMois▲

Private Sub CmbMois_AfterUpdate()
    MajTableauStats ' actualise le tableau des statistiques
End Sub

V-B-4. Liste déroulante cmbAnnee▲

Private Sub cmbAnnee_AfterUpdate()
    MajTableauStats ' actualise le tableau des statistiques
End Sub

V-B-5. Bouton de commande CmdMoisPrecedent▲

Private Sub CmdMoisPrecedent_Click()
    
    If CmbMois.Value = 1 Then ' si la liste indique le mois d'indice 1 (janvier)
        CmbMois.Value = 12 ' on passe au mois de décembre
        cmbAnnee.Value = cmbAnnee.Value - 1 ' et à l'année précédente
    Else
        CmbMois.Value = CmbMois.Value - 1 ' on passe au mois précedent
    End If
    
    MajTableauStats ' actualise le tableau des statistiques
End Sub

V-B-6. Bouton de commande CmdMoisSuivant▲

Private Sub CmdMoisSuivant_Click()

    If CmbMois.Value = 12 Then ' si la liste indique le mois d'indice 12 (décembre)
        CmbMois.Value = 1 ' on passe au 1er mois (janvier)
        cmbAnnee.Value = cmbAnnee.Value + 1 ' et à l'année suivant
    Else
        CmbMois.Value = CmbMois.Value + 1 ' on passe au mois suivant
    End If
    
    MajTableauStats ' actualise le tableau des statistiques
End Sub

V-B-7. Bouton de commande CmdAnneePrecedente▲

Private Sub CmdAnneePrecedente_Click()
    
    Me.cmbAnnee = Me.cmbAnnee - 1 ' on passe à l'année précédente.
    Me.CmbMois = 1 ' on recale la période sur le 1er mois
       
    MajTableauStats ' actualise le tableau des statistiques
End Sub

V-B-8. Bouton de commande CmdAnneeSuivante▲

Private Sub CmdAnneeSuivante_Click()

    Me.cmbAnnee = Me.cmbAnnee + 1 ' on passe à l'année suivante.
    Me.CmbMois = 1 ' on recale la période sur le 1er mois

    MajTableauStats ' actualise le tableau des statistiques
End Sub

V-B-9. Procédure sur Ouverture du formulaire▲

Private Sub Form_Open(Cancel As Integer)
    MajTableauStats ' actualise le tableau des statistiques
End Sub

Il est en mode tabulaire et à comme source de données la requête analyse croisée R_TableauStats, vue précédemment.

Il comporte les éléments suivants :

• Dans l'en-tête de page, 12 étiquettes pour afficher les 12 mois de la période choisie ;
• Dans le détail de l'état, la référence et la désignation de l'article ;
• Toujours dans le détail, 12 zones de texte affichant les montants enregistrés pour chaque mois.

VI-A-1. Etiquettes lblCol1..lblCol12▲

Positionnées dans l'en-tête de page, elles permettent d'afficher les 12 mois de la période choisie.

VI-A-2. Zones de texte txtRefArticle, txtDesigantionArticle▲

Placées dans le détail de l'état, elles affichent la référence et la désignation de chaque article.

VI-A-3. Zones de texte txtMois1..txtMois12▲

Disposées dans le détail de l'état, elles affichent les montants des articles pour chaque mois de la période choisie.

VI-A-4. Procédure sur ouverture de l'état▲

Private Sub Report_Open(Cancel As Integer)
    Dim i As Long, dt As Date
    ' date du 1er jour de la période choisie sur le formulaire F_TableauStats
    dt = DateSerial(Forms!F_TableauStats.cmbAnnee, Forms!F_TableauStats.CmbMois, 1)
    For i = 1 To 12 ' on parcourt les 12 étiquettes pour les 12 en-têtes de colonne
        ' on copie dans l'en-tête de la colonne d'indice i du sous-formulaire le mois correspondant à la date dt au format du type "0ct 19"
        Me("lblCol" & i).Caption = Format(dt, "mmm yy")
        dt = DateAdd("m", 1, dt)
    Next i
End Sub