Formulaire de planning pour la gestion des présences et des absences

Private Sub Form_Open(Cancel As Integer)
    Dim j As Long
    ...
    For j = 1 To 31 ' parcours des 31 zones de texte liées aux jours
        ' affectation de la fonction à la propriété OnDblClick des zones de texte liées aux jours
        Me("Jour" & j).OnDblClick = "=OuvrirFormSaisie(" & j & ")"
    Next j
End Sub

Private Sub cmbMois_AfterUpdate()
    ' Mise à jour du planning.
    MajPlanning
End Sub

Private Sub An_AfterUpdate()
    ' Mise à jour du planning.
    MajPlanning
End Sub

Private Sub CmdPrecedent_Click()

    If (Me.cmbMois.value > 1) Then ' Si le mois est supérieur à 1 (janvier),
        Me.cmbMois = Me.cmbMois.value- 1 ' affiche le mois précédent.
       
    Else ' sinon si le mois affiché est janvier (1er mois de l'année)
        Me.cmbMois = 12 ' affiche le dernier mois
        Me.cmbAnnee = Me.cmbAnnee - 1 ' et l'année précédente.
    End If
    MajPlanning ' actualise le planning
End Sub

Private Sub CmdSuivant_Click()

    If (Me.cmbMois.value < 12) Then ' Si le mois est inférieur à 12 (décembre),
        Me.cmbMois = Me.cmbMois.value + 1 ' affiche le mois suivant.
    Else ' sinon si le mois affiché est décembre (dernier mois de l'année)
        Me.cmbMois = 1 ' affiche le premier mois
        Me.cmbAnnee = Me.cmbAnnee + 1 ' et l'année suivante.
    End If
    MajPlanning ' actualise le planning
End Sub

Private Sub CmdValider_Click()
    ' Valide la saisie en enregistrant les changements dans la base et en actualisant le planning
    Dim n As Long, dd As Date, df As Date
    Dim rs As DAO.Recordset
    Dim db As DAO.Database
       
    If MsgBox("Souhaitez-vous ajouter des Absences/présences ?", vbYesNo + vbQuestion) = vbNo Then
       Exit Sub
    End If
    
    If (Nz(Me.IdMotifAbsence) <> "") Or (Nz(Me.NbHeures) <> "") Then ' si un motif d'absence ou un nombre d'heures a été saisis
        
        dd = CDate(Me!DateDebut) ' on copie dans la variable la date de début indiquée sur le formulaire
        df = CDate(Me!DateFin) ' on copie dans la variable la date de fin affichée sur le formulaire
                
        If (CDate(Me!DateDebut.Value) <= CDate(Me!DateFin.Value)) Then
           
            n = Nz(DLookup("IdPlanning", "T_Planning", "([IdPlanning]<>" & Nz(Me!IdPlanning.Value, 0) & ") and ([IdEmploye]=" & Nz(Me.IdEmploye.Value, 0) & ") and DateJour between " & FormatDateUs(dd) & " and " & FormatDateUs(df) & " and (PeriodeJour='" & Me.PeriodeJour & "')"), 0)
               
            If n = 0 Then ' période disponible, pas de présences pour cet employé sur cette période
            
                Set db = CurrentDb ' référence à la base courante
                Set rs = db.OpenRecordset("T_Planning", dbOpenDynaset) ' ouverture du recordset basé sur la table T_Planning
                
                dd = dd + 1
                
                Do While (dd <= df) ' parcourt des jours de la période
                   
                   ' Si pas un week-end ou un jour férié
                    If (Not EstWeekEnd(dd)) And Not (EstFerie(dd)) Then
                        rs.AddNew
                        rs!IdEmploye = Me.IdEmploye
                        rs!IdMotifAbsence = Nz(Me.IdMotifAbsence, Null)
                        rs!NbHeures = Nz(Me.NbHeures, Null)
                        rs!DateJour = dd
                        rs!PeriodeJour = Me.PeriodeJour
                        rs.Update
                    End If
                    
                    dd = dd + 1
                   
                Loop
                
                ' libération des varaibles
                rs.Close
                Set rs = Nothing
                
                Set db = Nothing
                
                Me.Requery ' enregistrement des changements
                MajPlanning ' rafraîchissement du planning
                
                DoCmd.Close acForm, Me.Name ' fermeture du formulaire de saisie
                
            Else
                MsgBox ("Saisie incorrecte : Dates indisponibles !")
            End If
            
        Else '
           MsgBox ("Saisie incorrecte : date de début postérieure à la date de fin !")
        End If
     
    Else
       MsgBox ("Saisir une Absence !")
    End If
End Sub

Private Sub CmdAnnuler_Click()
    Me.Undo ' annule la saisie
    DoCmd.Close acForm, "F_Saisie" ' ferme le formulaire
End Sub

Private Sub CmdSupprimer_Click()
    ' Supprime les absences ou présentes comprises dans la période saisie
    Dim dd As Date, df As Date
    
    If (MsgBox("Souhaitez-vous supprimer les Absences/présences sur cette période ?", vbYesNo + vbQuestion) = vbYes) Then
       
        dd = CDate(Me!DateDebut) ' copie dans la variable de la date de début saisie sur le formulaire
        df = CDate(Me!DateFin) ' copie dans la variable de la date de fint saisie sur le formulaire
        
        If (dd <= df) Then
                
            ' supprime les absences comprises entre la date de début et de fin excepté l'enregistrement courant sur le formulaire
            DoCmd.SetWarnings False
            DoCmd.RunSQL "delete * from T_Planning where ([IdPlanning]<>" & Nz(Me!IdPlanning.Value, 0) & ") and ([IdEmploye]=" & Nz(Me.IdEmploye.Value, 0) & ") and DateJour between " & FormatDateUs(df) & " and " & FormatDateUs(dd)
            DoCmd.SetWarnings True
            
            Me.Undo ' annule la saisie
            
            If Not (Me.RecordsetClone.EOF) Then
                Me.RecordsetClone.Delete ' supprime l'enregistrement courant
            End If
        
            MajPlanning ' rafraîchit le planning
            DoCmd.Close acForm, Me.Name ' ferme le formulaire de saisie
              
        Else
           
           MsgBox ("Saisir une date de début antérieure à la date de fin !")
           
        End If
    
    End If
End Sub