Créer un journal d'activité des utilisateurs d'une base Access

La base de données est utilisée en mode multi-utilisateurmultiutilisateurs, avec sur le serveur le fichier de données et sur les postes clients l'interface utilisateur :

On souhaite dans cette situation enregistrer dans une table les différentes opérations effectuées par les utilisateurs :

• mise à jour d'un enregistrement ;
• création d'un enregistrement ;
• suppression d'un enregistrement ;
• fermeture de l'application ;
• …

Pour cela, on met à jour la table en utilisant une procédure que l'on exécute sur des événements de formulaires :

• « Après MAJ » du formulaire ;
• « Après insertion » du formulaire ;
• « Sur suppression » du formulaire ;
• « Au clic » du bouton de commande permettant de quitter l'application ;
• …

Pour identifier la personne ayant déclenchée l'événement, on récupérera son nom d'utilisateur par deux méthodes au choix :

• méthode de la variable temporaireMéthode de la variable temporaire ;
• méthode de la variable environnementMéthode de la variable environnement.

Le journal des événements obtenu peut permettre ensuite :

• d'avoir une vision globale de l'activité de chaque utilisateur ;
• de savoir quels sont les services de l'application les plus et les moins utilisés ;
• en cas d'incident, d'aider à identifier son origine et de savoir qui a fait quoi ;
• d'avoir une trace des modifications effectuées sur les données sensibles ;
• …

On décrit par la suite les différentes étapes permettant de mettre en place ce système d'enregistrement de l'activité de chacun.

II-A. Table T_Evenement▲

II-B. Table T_Utilisateur▲

III-A. Méthode de la variable temporaire▲

Application.TempVars.Add "NomUtilisateur", "Dupont"

strNomUtilisateur=Application.TempVars("NomUtilisateur").Value

strNomUtilisateur=Me.txtNomUtilisateur ' copie du nom d'utilisateur dans une variable
Application.TempVars.Add "NomUtilisateur", strNomUtilisateur ' création de la variable temporaire

strNomUtilisateur=Application.TempVars("NomUtilisateur").Value

III-B. Méthode de la variable environnement▲

? Environ("UserName")

strNomUtilisateur=Environ("UserName")

Elle va copier dans la table des événements les informations relatives à l'événement déclenché :

• la date et l'heure actuelles ;
• le nom de l'objet : formulaire ou état ;
• le type d'événement déclenché ;
• l'identifiant de l'enregistrement ;
• le nom de l'utilisateur actif.

La procédure ouvre un Recordset pour insérer dans la table, en plus de la date et du nom d'utilisateur, les données passées en arguments :

Public Sub AjouterEvenement(ByVal TypeEvenement As String, ByVal IdEnregistrement As Long, Optional NomObjet As String = "")
    Dim db As DAO.Database ' variable pour faire référence à la base courante
    Dim rs As DAO.Recordset ' variable pour faire référence au Recordset lié à la table T_Evenement
    
    Set db = CurrentDb ' Référence à la base courante
    Set rs = db.OpenRecordset("T_Evenement", dbOpenDynaset) 'Ouverture du Recordset lié à la table T_Evenement
    If NomObjet = "" Then ' si pas de nom d'objet de spécifié en argument de la procédure
        NomObjet = Application.CodeContextObject.Name ' on copie le nom de l'objet dans lequel le code est en cours d'exécution
    End If
    rs.AddNew ' ajout dans la table des informations relatives à l'événement
    rs!DateEvenement = Now() ' copie dans la table de la date et de l'heure actuelles
    rs!NomObjet = NomObjet ' copie du nom de l'objet : formulaire, état
    rs!TypeEvenement = TypeEvenement ' copie du type d'événement : modification, ajout, suppression d'un enrg.
    rs!IdEnregistrement = IdEnregistrement ' copie de l'identifiant de l'enregistrement
    'rs!NomUtilisateur = Environ("username") ' copie du nom d'utilisateur contenu dans la variable d'environnement Username
    rs!NomUtilisateur = Application.TempVars("NomUtilisateur").Value ' copie du nom d'utilisateur contenu dans la variable temporaire NomUtilisateur
    rs.Update
    
    'libération des variables objet
    rs.Close
    Set rs = Nothing
    Set db = Nothing
End Sub

Avec cet argument optionnel, on laisse aussi la possibilité au programmeur débutant de définir un nom d'objet plus explicite, comme « Formulaire de saisie des clients ».

Dans notre exemple, on choisit un formulaire tout simple pour gérer les clients.

Pour enregistrer les opérations effectuées par les utilisateurs dans le formulaire, on a besoin de mettre sur différents événements, des appels à cette procédure :

V-A. Appel sur l'événement « Après MAJ » du formulaire▲

Private Sub Form_AfterUpdate()
    ' Ajout des informations concernant l'événement AfterUpdate déclenché dans le formulaire F_Client
    AjoutEvenement "Modification enregistrement dans formulaire", Me.IdClient
End Sub

V-B. Appel sur l'événement « Après insertion » du formulaire▲

Private Sub Form_AfterInsert()
    ' Ajout des informations concernant l'événement AfterInsert déclenché dans le formulaire F_Client
    AjoutEvenement "Insertion enregistrement dans formulaire", Me.IdClient
End Sub

V-C. Appel sur l'événement « Sur suppression » du formulaire▲

Private Sub Form_Delete(Cancel As Integer)
    ' Ajout des informations concernant l'événement Delete déclenché dans le formulaire F_Client
    AjoutEvenement "Suppression enregistrement dans formulaire", Me.IdClient
End Sub

Une fois le système d'enregistrement de l'activité des utilisateurs mis en place, libre à vous de construire votre propre interface pour afficher le journal des événements déclenchés.

On peut par exemple afficher le journal des événements par type d'événement, par objet, et par nom d'utilisateur :

VII-A. Récupération des données▲

VII-B. Purge des données▲

DELETE
FROM T_Evenement
WHERE DateEvenement<=DateAdd("m",-3,Date());

La base jointejournal-activite-utilisateurs est au format accdb.

Je tiens à remercier zoom61, gaby277 et chrtophe pour m'avoir conseillé pour la réalisation de cet article, ainsi que Claude Leloup pour sa relecture.