Créer une application Access pour gérer des interventions récurrentes

Private Sub IDIntervention_DblClick(Cancel As Integer)
    DoCmd.OpenForm "F_Intervention", , , "IDIntervention=" & Nz(Me.IDIntervention, 0)
End Sub

Public Sub RefreshListeInterventions()
    Dim sSQL As String ' variable contenant le code SQL pour filtrer la liste des interventions selon certains critères
    Dim sWhere As String ' variable contenant le critère pour filtrer la liste des interventions selon certains critères
       
    ' Constitution du critère SQL initial
    sWhere = " DateIntervention between #" & Format(Nz(Me!txtDateDebut, #1/1/1000#), "mm/dd/yyyy") & "# and #" & Format(Nz(Me!txtDateFin, #1/1/4000#), "mm/dd/yyyy") & "#"
    
    ' si on a choisi de filtrer selon un type d'intervention
    If (Nz(Me.lstTypeIntervention) <> "") And (Me.lstTypeIntervention <> "[Tous]") Then
        ' ajout de la condition dans le where
        sWhere = sWhere & " and ([TypeIntervention] like """ & Me.lstTypeIntervention & """)"
    Else
        Me.lstTypeIntervention = "[Tous]"
    End If
    
    ' si on a choisi de filtrer selon un client
    If (Nz(Me.cmbClient) <> "") And (Me.cmbClient <> "[Tous]") Then
        ' ajout de la condition dans le where
        sWhere = sWhere & " and ([nomClient] like """ & Me.cmbClient & """)"
    Else
        Me.cmbClient = "[Tous]"
    End If
    
    ' si on a choisi de filtrer selon un technicien
    If (Nz(Me.cmbTechnicien) <> "") And (Me.cmbTechnicien <> "[Tous]") Then
        ' ajout de la condition dans le where
        sWhere = sWhere & " and ([Technicien] like """ & Me.cmbTechnicien & """)"
    Else
        Me.cmbTechnicien = "[Tous]"
    End If
    ' consitution du code SQL complet avec les clauses select et where
    sSQL = "Select * From R_ListeInterventions where" & sWhere & " order by [DateIntervention] asc, HeureIntervention Asc, IDIntervention Asc;"
    ' affectation du code SQL à la propriété RecordSource du sous-formulaire SF_ListeInterventions
    Me.SF_ListeInterventions.Form.RecordSource = sSQL
End Sub

Private Sub cmbClient_AfterUpdate()
    RefreshListeInterventions ' rafraîchit la liste des interventions
End Sub

Private Sub cmbTechnicien_AfterUpdate()
    RefreshListeInterventions ' rafraîchit la liste des interventions
End Sub

Private Sub lstTypeIntervention_AfterUpdate()
    RefreshListeInterventions ' rafraîchit la liste des interventions
End Sub

Private Sub txtDateDebut_AfterUpdate()
    If Me.cmbParamDate.Value = "Jour" Then ' si on choisit de filtrer sur un jour
        If Not IsNull(Me.txtDateDebut) Then
            Me.txtDateFin.Value = CDate(Me.txtDateDebut.Value) ' on copie la date de début dans la zone de texte txtDateFin
        Else ' sinon
            Me.txtDateFin.Value = Null ' on vide la zone de texte txtDateFin
        End If
    End If
    RefreshListeInterventions ' rafraîchit la liste des interventions
End Sub

Private Sub txtDateFin_AfterUpdate()
    RefreshListeInterventions ' rafraîchit la liste des interventions
End Sub

Private Sub CmdAjouterIntervention_Click()
    ' Ouvre le formulaire F_Intervention en mode ajout
    DoCmd.OpenForm "F_Intervention", , , , acFormAdd
    ' Copie dans le formulaire F_Intervention la date affichée dans la zone de texte txtDateDebut comme date d'intervention
    Forms!F_Intervention!DateIntervention = CDate(Me.txtDateDebut)
End Sub

Private Sub Form_Open(Cancel As Integer)
    Me.txtDateDebut = Date ' copie la date du jour dans la zone de texte txtDateDebut
    Me.txtDateFin = Date ' copie la date du jour dans la zone de texte txtDateFin
    RefreshListeInterventions ' rafraîchit la liste des interventions en fonction des choix
End Sub

Private Sub CmdValider_Click()
    ' Valide la saisie
    
    If Nz(Me.IDClient) = "" Then ' si pas de client de choisi
        MsgBox ("Saisir un client !") ' on affiche une alerte !
        Exit Sub ' on sort de la procédure
    End If
    
    If Nz(Me.IDTechnicien) = "" Then ' si pas de technicien de choisi
        MsgBox ("Saisir un employé !") ' on affiche une alerte !
        Exit Sub ' on sort de la procédure
    End If
    
    Me.Refresh ' on enregistre les modifications apportées au formulaire
    If (Me.optEstPeriodique.Value = True) Then ' si l'intervention est périodique
        GenererInterventions (Me.IDIntervention) ' on génère les interventions suivant la périodicité
    End If
    ' on actualise le sous-formulaire affichant la liste des interventions
    Forms!F_ListeInterventions.SF_ListeInterventions.Requery
    ' on ferme le formulaire
    DoCmd.Close acForm, "F_Intervention"
End Sub

Private Sub CmdAnnuler_Click()
    Me.Undo ' on annule la saisie
    DoCmd.Close acForm, "F_Intervention" ' on ferme le formulaire
End Sub

Private Sub CmdSupprimer_Click()
    ' Supprime l'enregistrement en cours
   
    If (MsgBox("Souhaitez-vous supprimer l'enregistrement ?", vbYesNo + vbQuestion) = vbYes) Then ' si on confirme la suppression
       
        If Not (Me.Recordset.EOF) Then ' si on est sur un enregistrement
            Me.Recordset.Delete ' on supprime l'enregistrement
        End If
        ' on actualise le sous-formulaire affichant la liste des interventions
        Forms!F_ListeInterventions.SF_ListeInterventions.Requery
        ' on ferme le formulaire
        DoCmd.Close acForm, "F_Intervention"
    End If
End Sub

Private Sub CmdSupprimerPeriodicite_Click()
    If MsgBox("Souhaitez-vous supprimer tous les enregistrements de la périodicité ?", vbYesNo + vbQuestion) = vbYes Then ' si on confirme la suppression
        ' on exécute la requête pour supprimer la périodicité et ses interventions
        CurrentDb.Execute "delete from T_Periodicite where (IdPeriodicite=" & Nz(Me.IdPeriodicite, 0) & ");", dbFailOnError
        ' on actualise le sous-formulaire affichant la liste des interventions
        Forms!F_ListeInterventions.SF_ListeInterventions.Requery
        ' on ferme le formulaire
        DoCmd.Close acForm, "F_Intervention"
    End If
End Sub