Documentation de l'application Gestion de stock

Private Sub Cmd_Liste_Materiels_Click()
    DoCmd.OpenForm "F_LISTE_MATERIELS"
End Sub

Private Sub Cmd_Ajouter_Fiche_Fournisseur_Click()
    DoCmd.OpenForm "F_FOURNISSEUR", , , , acFormAdd
End Sub

Private Sub Cmb_Categorie_Materiel_AfterUpdate()
    ' rafraîchit la liste des matériels en fonction des choix effectués sur les listes déroulantes
    RefreshListeMateriels
End Sub

Public Function IsOpenOutlook() As Boolean
    Dim olkApp As Outlook.Application ' variable objet pour faire référence à l'application Outlook

    On Error Resume Next ' passe à la ligne suivante en cas d'erreur
    Set olkApp = GetObject(, "Outlook.Application")
    On Error GoTo 0 ' annule la gestion d'erreur

    If olkApp Is Nothing Then ' si Outlook n'est pas ouvert
        IsOpenOutlook = False
    Else ' sinon
        IsOpenOutlook = True
    End If

End Function

Sub sendEmail(olkApp As Object, emailAddr As String, subj As String, msg As String)
    ' envoie l'e-mail d'objet subj et de contenu msg à l'adresse emailAddr
    Dim emailItem As olMailitem ' variable objet pour faire référence à l'objet MailItem
 
    ' Création de l'objet olMailitem
    Set emailItem = olkApp.CreateItem(olMailItem)
    
    With emailItem ' mise à jour des propriétés de l'objet olMailItem
        .To = emailAddr ' adresse e-mail du destinataire
        .Subject = subj ' objet du message
        .BodyFormat = olFormatRichText ' format texte enrichi pour le message
        .HTMLBody = msg ' contenu du message
        .Send ' envoi du message
    End With
    
    ' on libère la variable objet
    Set emailItem = Nothing

End Sub

Public Function SendAlertes(obj As" String, msg As String) As Boolean
    ' fonction permettant d'envoyer une alerte aux utilisateurs dont la garantie du matériel arrive à échéance
    On Error GoTo err_SendAlertes ' gestion d'erreur
    Dim db As DAO.Database ' variable pour faire référence à la base de données
    Dim rsAlertes As DAO.Recordset ' variable pour faire référence au recordset lié à la requête affichant la liste des alertes
    Dim olkApp As Object
    Dim msg2 As String

    
    Set db = CurrentDb ' référence à la base courante
    Set rsAlertes = db.OpenRecordset("R_Liste_Alertes_Garanties", dbOpenDynaset) ' ouverture du recordset basé sur la requête R_Liste_Alertes_Garanties
    
    If Not IsOpenOutlook() Then ' teste si Outlook est ouvert
        Dim wsShell As Object
        Set wsShell = CreateObject("WScript.Shell")
        Call wsShell.Run("outlook", 1, True) ' lance Outlook si pas ouvert
    End If
    
    Set olkApp = CreateObject("Outlook.application") ' créer l'objet application d'Outlook
    
    Do Until rsAlertes.EOF ' on parcourt les alertes
        
        If Nz(rsAlertes!E_MAIL, "") <> "" Then ' si l'utilisateur a une adresse e-mail de renseignée
        
            msg2 = Replace(msg, "FABRICANT_MATERIEL", rsAlertes!FABRICANT)
            msg2 = Replace(msg2, "MODELE_MATERIEL", rsAlertes!MODELE)

            sendEmail olkApp, rsAlertes!E_MAIL, obj, msg2 ' envoie de l'e-mail à l'utilisateur
            
        End If
        
        rsAlertes.Edit
        rsAlertes!ALERTE_GARANTIE = True ' on met la valeur du champ ALERTE_GARANTIE à True
        rsAlertes.Update
        
        rsAlertes.MoveNext ' on passe à l'alerte suivante
    
    Loop
    
    
    SendAlertes = True ' on renvoie True pour indiquer que tout s'est bien passé
    
err_SendAlertes:

    If (Err.Number <> 0) And (SendAlertes = False) Then ' en cas d'erreur
        MsgBox (Err.Description) ' affichage du message d'erreur
    End If
    
    On Error Resume Next
    ' on ferme et libère les variables
    If Not rsAlertes Is Nothing Then
        rsAlertes.Close
    End If
    Set rsAlertes = Nothing
    
    Set db = Nothing
    
    Set olkApp = Nothing
    
End Function