obPlanning.Row=3

obPlanning.Col=3

obPlanning.Rows=30

obPlanning.Cols=7

obPlanning.RowsHeight=25

obPlanning.ColsWidth=125

obPlanning.BackColor=vbWhite

obPlanning.GridColor=vbBlack

obPlanning.FieldsCols=2

obPlanning.FieldsColsWidth=100

obPlanning.FieldsColor=vbGrey

obPlanning.RefControleImage = Me.imPlanning

obPlanning.InitImage

Public Sub Clear()
Dim i As Integer, j As Integer
Dim l As Integer, w As Integer, h As Integer
Dim lReturn As Boolean

' Largeur totale des en-têtes de lignes (colonnes de gauche).
l = vFieldsCols * vFieldsColsWidth

' Largeur totale du planning sans les en-têtes de lignes.
w = vCols * vColsWidth

' Hauteur totale du planning sans les en-têtes de colonnes.
h = vRows * vRowsHeight

' Supprime toutes les régions du planning précédemment créées.
lReturn = obGdiP.DeleteAllRegions

' On dessine les rectangles du planning : le rectangle des en-têtes de lignes 
' (à gauche du planning) en gris et le rectangle du planning en blanc.

lReturn = obGdiP.DrawRectangle(0, 0, l, h, vFieldsColor, vGridColor, 1)
lReturn = obGdiP.DrawRectangle(l, 0, l + w, h, vBackColor, vGridColor, 1)

' On dessine les lignes horizontales composant le planning.

For i = 1 To vRows
   lReturn = obGdiP.DrawLine(0, i * vRowsHeight, _ 
                             l + w, i * vRowsHeight, vGridColor, 1, False)
Next i

' On dessine les lignes verticales composant le planning.

For i = 1 To vFieldsCols
   lReturn = obGdiP.DrawLine(i * vFieldsColsWidth, 0, _ 
                             i * vFieldsColsWidth, h, vGridColor, 1, False)
Next i

For i = 1 To vCols
   lReturn = obGdiP.DrawLine(l + i * vColsWidth, _ 
                             0, l + i * vColsWidth, h, vGridColor, 1, False)
Next i

' Création des vRows*vCols régions; 
' chaque région portant le nom de ses indices de ligne et de colonne :
' Par exemple la région de ligne 5 et de colonne 3 portera le nom "5_3".

For i = 1 To vRows

For j = 1 To vCols
   lReturn = obGdiP.CreateRegionRect(i & "_" & j, l + (j - 1) * vColsWidth, _ 
             (i - 1) * vRowsHeight, l + j * vColsWidth - 1, i * vRowsHeight - 1)
Next j

Next i

End Sub

obPlanning.refresh

obPlanning.DrawRect 1, 1, 1, 3, vbBlue, vbBlack, 1

obPlanning.DrawText 1, 1, 1, 3, "DUPONT", 12, 0,0 vbBlue

obPlanning.DrawFieldText 1, 2, "DWC", 12, 0, 0, vbBlue

obPlanning.GetRectXY(CLng(X), CLng(Y), Row1, Col1, Row2, Col2) 

obPlanning.KeepImage

obPlanning.ResetImage

Public Sub ColorCol(IndCol As Integer, BackColor As Long)
Dim IndRow As Integer ' Indice de ligne.

For IndRow = 1 To Rows
' Dessine à l'intersection entre la ligne IndRow et la colonne IndCol 
' un rectangle de couleur de fond BackColor.
DrawRect IndRow, IndCol, IndRow, IndCol, BackColor, vbBlack, 1

Next IndRow

End Sub

obPlanning.ColorCol 16, vbRed

Option Compare Database

'****************************************************************************************
'*                                    PARTIE DECLARATIVE                                *
'****************************************************************************************

'----------------------------------------------------------------------------------------
' Ces 2 variables sont accessibles dans tout le projet.
' Une fois instanciées, elles permettent de paramétrer le planning, puis
' de dessiner par dessus.
'----------------------------------------------------------------------------------------
Public obHeader As clPlanning
Public obPlanning As clPlanning

'----------------------------------------------------------------------------------------
' La date du premier jour du planning correspondant à la 1ère colonne.
' Cette variable est accessible dans tout le projet.
'----------------------------------------------------------------------------------------
Public DateDebut As Date


'****************************************************************************************
'*                                    SUITE DU MODULE                                   *
'****************************************************************************************

'----------------------------------------------------------------------------------------
' Vous pouvez définir vos procédures et fonctions de gestion du planning à la suite.
' ...
'----------------------------------------------------------------------------------------

'----------------------------------------------------------------------------------------
' Exemple de code :
' Fonction de conversion d'un indice de colonne en son jour correpondant sur le planning.
'----------------------------------------------------------------------------------------
Public Function ConversionColonneVersJour(ByVal Colonne As Integer) As Date
ConversionColonneVersJour = (DateDebut + Colonne - 1)
End Function

'----------------------------------------------------------------------------------------
' Autre exemple de code :
' Fonction de conversion d'une date en indice de colonne correpondant sur le planning.
'----------------------------------------------------------------------------------------
Public Function ConversionJourVersColonne(ByVal Jour As Date) As Integer
ConversionJourVersColonne = (Jour - DateDebut + 1)
End Function

Private Sub Form_Load()

' Création des instances de classes pour les en-têtes de colonnes (obHeader)
' et pour le planning (obPlanning).

Set obHeader = New clPlanning
Set obPlanning = New clPlanning

' Spécification du contrôle image imHeader sur lequel on va dessiner les en-têtes de colonnes. 
' Puis, initialisation de l'image et affectation des paramètres pour les en-têtes de colonnes.
     
   With obHeader
      .RefControleImage = Me.imHeader
      .InitImage
      .FieldsCols = 2
      .FieldsColsWidth = 70
      .FieldsColor = -2147483633
      .Rows = 1
      .RowsHeight = 25
      .Cols = 31
      .ColsWidth = 27
      .BackColor = -2147483633
   End With
 
' Spécification du contrôle image imPlanning sur lequel on va dessiner le planning. 
' Puis, initialisation de l'image et affectation des paramètres pour le planning.
   
   With obPlanning
      .RefControleImage = Me.imPlanning
      .InitImage
      .FieldsCols = 2
      .FieldsColsWidth = 70
      .Rows = 40
      .Cols = 31
      .ColsWidth = 27
   End With

' On dessine les en-têtes et le planning sur les contrôles images.

obHeader.Clear
obHeader.Refresh

obPlanning.Clear
obPlanning.Refresh

End Sub

Private Sub Form_Close()
' On libère les variables.

Set obHeader = Nothing
Set obPlanning = Nothing

End Sub

Private Sub imPlanning_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
' Indices de lignes et de colonnes pour le rectangle du planning.
Dim Row1 As Integer, Col1 As Integer, Row2 As Integer, Col2 As Integer 

' Identifie les coordonnées du rectangle situé sur le point (X,Y).
obPlanning.GetRectXY CLng(X), CLng(Y), Row1, Col1, Row2, Col2

   If (Row1 > 0) Then ' Si un rectangle existe.
                          
      obPlanning.ResetImage ' Restitue l'image du planning sauvegardée en mémoire.
                          
      ' Dessine un cadre autour du rectangle de coordonnées (Row1,Col1,Row2,Col2).
      obPlanning.DrawRect Row1, Col1, Row2, Col2, -1, vbBlack, 2
      obPlanning.Refresh
      
   End If

End Sub

Private Sub imPlanning_DblClick(Cancel As Integer)  
    
   ' S'il y a bien une zone sélectionnée sur le planning. 
   If (obPlanning.Row > 0) And (obPlanning.Col > 0) Then
      ' Exemple de code : 
      ' Jour = ConversionColonneVersJour(obPlanning.Col)
      ' DoCmd.OpenForm "F_Saisie"... 
   End If

End Sub

Private Sub cmTester_Click()
Dim i As Integer
Dim DateJ As Date
Dim Col1 As Integer, Col2 As Integer ' Indices de colonnes sur le planning.

' Met à jour les en-têtes de colonnes avec les 31 jours du mois de janvier par exemple.

obHeader.DrawFieldText 1, 1, "NCh.", 12, 0, 1
obHeader.DrawFieldText 1, 2, "TCh.", 12, 0, 1

DateDebut = CDate("01/01/2009")
DateJ = DateDebut

For i = 1 To 31
obHeader.DrawText 1, i, 1, i, Day(DateJ), 12, 1, 1, vbBlack, False
DateJ = DateJ + 1
Next i


' Ecrit du texte dans les en-têtes de la ligne 1.

obPlanning.DrawFieldText 1, 1, "001", 12, 0, 1
obPlanning.DrawFieldText 1, 2, "DWC", 12, 0, 1

' Dessine 1 rectangle d'une couleur donnée sur la 1ère ligne du planning.

' Conversion de la date de début en indice de colonne.
Col1 = ConversionJourVersColonne(CDate("01/01/2009"))
' Conversion de la date de fin en indice de colonne.
Col2 = ConversionJourVersColonne(CDate("03/01/2009"))
' Dessine le rectangle correspondant.
obPlanning.DrawRect 1, Col1, 1, Col2, vbMagenta, obPlanning.GridColor, 1
obPlanning.DrawText 1, Col1, 1, Col2, "DUPONT", 12, 1, 1, vbBlack, False


' Ecrit du texte dans les en-têtes de la ligne 2.

obPlanning.DrawFieldText 2, 1, "002", 12, 0, 1
obPlanning.DrawFieldText 2, 2, "BWC", 12, 0, 1

' Dessine 1 rectangle d'une couleur donnée sur la 2ème ligne du planning.

' Conversion de la date de début en indice de colonne.
Col1 = ConversionJourVersColonne(CDate("03/01/2009"))
' Conversion de la date de fin en indice de colonne.
Col2 = ConversionJourVersColonne(CDate("06/01/2009"))
' Dessine le rectangle correspondant.
obPlanning.DrawRect 2, Col1, 2, Col2, vbGreen, obPlanning.GridColor, 1
obPlanning.DrawText 2, Col1, 2, Col2, "DURAND", 12, 1, 1, vbBlack, False


' Raffraichit les contrôles images.

obPlanning.KeepImage

obHeader.Refresh
obPlanning.Refresh

End Sub

Private Sub cmEffacer_Click()

' Efface le contenu du planning.

obHeader.Clear
obHeader.Refresh

obPlanning.Clear
obPlanning.Refresh

End Sub