Créer une gestion des droits des utilisateurs avec Access

La gestion des droits des utilisateurs ayant été abandonnée depuis Access 2007, on propose dans cet article de décrire comment mettre en place son propre système de gestion des autorisations.

La base de données est utilisée en mode multiutilisateurmultiutilisateurs, avec sur le serveur le fichier de données et sur les postes clients l'interface utilisateur :

On souhaite dans cette situation enregistrer dans des tables côté serveur les autorisations des utilisateurs :

• ajout des données ;
• suppression des données ;
• modification des données ;
• accès aux données confidentielles ;
• …

Puis, exécuter une procédure permettant de paramétrer les formulaires en fonction des droits accordés à l'utilisateur :

• propriété « ajout autorisé » à Oui ;
• propriété « suppr autorisée » à Oui ;
• propriété « modif autorisée » à Oui ;
• bouton de commande « droits utilisateur » activé ;
• …

Le système comportera également un formulaire d'authentification lancé au démarrage et du code pour masquer les objets de la base à son ouverture.

Pour identifier la personne ayant ouvert la session, on récupérera son nom d'utilisateur par la méthode de la variable temporaireFormulaire d'authentification.

Enfin, en complément, on expliquera au lecteur comment désactiver la touche MAJ pour forcer l'ouverture du formulaire au démarrage, et comment protéger la base par mot de passe.

Détaillons tout d'abord la structure des tables contenues dans le fichier de données côté serveur.

II-A. Table T_Utilisateur▲

II-B. Table T_Groupe▲

II-C. Table T_Droit_Formulaire▲

II-D. Table T_Droit_Controle▲

Présentons ensuite brièvement la structure des requêtes permettant d'afficher les droits pour chaque utilisateur.

III-A. R_Droit_Formulaire▲

Elle relie les tables T_Utilisateur et T_Droit_Formulaire.

III-B. R_Droit_Controle▲

Elle fait le lien entre les tables T_Utilisateur et T_Droit_Controle.

Le formulaire F_Groupe va permettre à l'administrateur de la base de données de définir les autorisations accordées aux groupes d'utilisateurs au niveau des formulaires et des contrôles. Il est basé sur la table T_Groupe et permet d'enregistrer les droits dans des sous-formulaires.

Ensuite, le formulaire F_Utilisateur permet de choisir un groupe pour un utilisateur et ainsi de lui accorder certains droits :

Il s'agit d'exemples de formulaires présents dans l'application côté client, libre à vous de réaliser vos propres interfaces utilisateur pour attribuer les droits.

Il va permettre d'identifier l'utilisateur et de copier son nom dans une variable temporaire pour en disposer durant toute la session.

Les propriétés Fenêtre contextuelle et Fenêtre Modale, doivent être définies sur Oui, et la propriété Bouton Fermer sur Non :

À l'ouverture du formulaire, on va en plus masquer par du code le volet de navigation et le ruban :

Private Sub Form_Open(Cancel As Integer)
    DoCmd.NavigateTo "acNavigationCategoryObjectType"
    DoCmd.RunCommand acCmdWindowHide ' on masque le volet de navigation
    DoCmd.ShowToolbar "Ribbon", acToolbarNo ' on masque le ruban
End Sub

Ce formulaire est chargé au démarrage de l'application installée sur les postes clients. On peut le paramétrer facilement dans les options Access :

On utilise une variable temporairevariable temporaire pour copier le nom d'utilisateur et en disposer au cours de la session entière.

Par exemple, la création d'une variable NomUtilisateur contenant le nom « Dupont » est réalisée simplement en invoquant la méthode Add de la collection Application.TempVars :

Application.TempVars.Add "NomUtilisateur", "Dupont"

Pour obtenir la valeur contenue dans cette variable, il suffit de faire :

strNomUtilisateur=Application.TempVars("NomUtilisateur").Value

La création de la variable peut se faire au moment de la connexion en exécutant par exemple le code :

strNomUtilisateur=Me.txtNomUtilisateur ' copie du nom d'utilisateur dans une variable
Application.TempVars.Add "NomUtilisateur", strNomUtilisateur ' création de la variable temporaire

La récupération du contenu de la variable temporaire se fait donc simplement par :

strNomUtilisateur=Application.TempVars("NomUtilisateur").Value

Elle va paramétrer le formulaire actif en fonction des autorisations accordées aux utilisateurs :

• ajout autorisé ;
• suppr autorisée ;
• modif autorisée ;
• contrôle « cmdOpenFormUsers » activé ;
• …

Déroulé de la procédure

1. Copie du nom d'utilisateur et du nom du formulaire dans des variables ;
2. Ouverture du recordset basé sur la requête R_Droit_Formulaire filtrée avec le nom de l'utilisateur et du formulaire ;
3. Paramétrage du formulaire en fonction des autorisations enregistrées dans la table ;
4. Ouverture du recordset basé sur la requête R_Droit_Controle filtrée avec le nom de l'utilisateur et du formulaire ;
5. Activation ou désactivation des contrôles du formulaire en fonction des autorisations enregistrées dans la table.

Public Sub configFormulaire()
    ' Configurer le formulaire en fonction des autorisations accordées à l'utilisateur
    Dim strNomFormulaire As String ' variable contenant le nom du formulaire
    Dim strNomControle As String ' variable contenant le nom du contrôle situé dans le formulaire
    Dim strNomUtilisateur As String ' variable contenant le nom d'utilisateur
    Dim strDroit As String ' variable contenant le droit de l'utilisateur
    Dim dbs As DAO.Database ' variable pour faire référence à la base courante
    Dim rstDroitsUsers As DAO.Recordset ' variable pour faire référence au recordset basé sur la requête R_Droits_Utilisateurs
    Dim frm As Form ' variable objet pour faire référence au formulaire actif
    
    strNomFormulaire = CodeContextObject.Name ' on copie le nom de l'objet dans lequel le code est en cours d'exécution
    
    Set frm = CodeContextObject ' référence au formulaire actif
    
    strNomUtilisateur = Application.TempVars("NomUtilisateur").Value ' copie du nom d'utilisateur contenu dans la variable temporaire NomUtilisateur
    
    Set dbs = CurrentDb ' référence à la base courante
    
    ' ouverture du recordset basé sur la requête R_Droit_Formulaire filtrée en fonction du nom d'utilisateur et du nom du formulaire
    Set rstDroitsUsers = dbs.OpenRecordSet("select * from R_Droit_Formulaire " & _
                                            "where (NomUtilisateur like """ & strNomUtilisateur & """) and (NomFormulaire like """ & strNomFormulaire & """)")
    
    Do While Not rstDroitsUsers.EOF  ' on parcourt les droits autorisés pour l'utilisateur sur le formulaire
        
        strDroit = rstDroitsUsers!Droit ' on copie le droit dans la variable
        
        If strDroit = "Ajout autorisé" Then ' si ajout autorisé
            frm.AllowAdditions = rstDroitsUsers!Coche
        Else
            If strDroit = "Suppression autorisée" Then ' si suppression autorisée
                frm.AllowDeletions = rstDroitsUsers!Coche
            Else ' si modif autorisée
                frm.AllowEdits = rstDroitsUsers!Coche
            End If
        End If
        
        rstDroitsUsers.MoveNext ' on se déplace sur le prochain enregistrement
     
    Loop
    
    rstDroitsUsers.Close ' fermeture du recordset
    
    ' ouverture du recordset basé sur R_Droit_Controle filtré en fonction du nom d'utilisateur et du nom du formulaire
     Set rstDroitsUsers = dbs.OpenRecordSet("select * from R_Droit_Controle " & _
                                            "where (NomUtilisateur like """ & strNomUtilisateur & """) and (NomFormulaire like """ & strNomFormulaire & """)")
  

    Do While Not rstDroitsUsers.EOF  ' on parcourt les droits autorisés pour l'utilisateur sur les contrôles du formulaire
        
        strNomControle = rstDroitsUsers!NomControle ' on copie le nom du contrôle dans la variable
        frm(strNomControle).Enabled = rstDroitsUsers!Actif ' on active ou pas le contrôle suivant l'autorisation accordée
        
        rstDroitsUsers.MoveNext ' on se déplace sur le prochain enregistrement
        
    Loop
    
    ' libération des variables
    
    Set frm = Nothing
    
    rstDroitsUsers.Close
    Set rstDroitsUsers = Nothing
    
    Set dbs = CurrentDb
End Sub

La procédure doit être copiée dans un module standard pour être appelée sur l'événement ouverture des formulaires.

Dans notre exemple, on choisit un formulaire tout simple pour gérer les clients.

Pour configurer le formulaire en fonction des droits utilisateur, on a besoin de mettre sur l'événement « Sur ouverture » du formulaire, un appel à cette procédure :

L’événement Sur ouverture ou Open se produit lorsqu’un formulaire est ouvert, mais avant l’affichage du premier enregistrement. On exécute alors la procédure permettant de paramétrer le formulaire en fonction des autorisations définies dans les tables :

Private Sub Form_Open(Cancel As Integer)
    configFormulaire ' paramètre le formulaire en fonction des autorisations accordées à l'utilisateur (ajout, suppression, modification)
End Sub

IX-A. Désactiver la touche MAJ▲

call SetBypassProperty

IX-B. Définir un mot de passe▲

Vous pouvez également définir un mot de passe pour votre base de données côté serveur, pour éviter qu'un tiers puisse accéder à vos données par un autre moyen. Pour cela, il faut d'abord ouvrir votre fichier Access en mode exclusif  :

1. Sous l’onglet Fichier, cliquez sur Ouvrir :
2. Dans la boîte de dialogue Ouvrir, recherchez le fichier à ouvrir, puis sélectionnez-le ;
3. Cliquez sur la flèche en regard du bouton Ouvrir et cliquez sur Ouvrir en exclusif. La figure suivante illustre le menu :

Puis, définir votre mot de passe depuis le menu Informations :

1. Sous l’onglet Fichier, cliquez sur Informations, puis sur Chiffrer avec mot de passe :
2. La boîte de dialogue « Définir le mot de passe de la base de données » s’affiche :
3. Tapez votre mot de passe dans la zone Mot de passe, retapez-le dans la zone Confirmation, puis cliquez sur OK.

Si maintenant une tierce personne tente d'importer les objets de la base de données, elle est alors contrainte de fournir le mot de passe.

De même, si elle souhaite accéder à la base distante en utilisant du code VBA, elle doit également spécifier le mot de passe dans la chaîne de connexion :

 

Sélectionnez

Dim dbs As DAO.Database
Dim strConnexion As String
Dim strCheminBase As String
' Les infos sur la base (chemin et paramètres de connexion)
strCheminBase = "C:....accdb"
strConnexion = "MS Access;pwd=votre_mot_de_passe"
' On ouvre la base de données
Set dbs = OpenDatabase(strCheminBase, False, False, strConnexion)
Debug.Print "Base de données ouverte !"
...

Cependant, elle aurait toujours la possibilité d'importer les objets et notamment les liens présents dans la frontale, et ainsi d'accéder aux données de la base distante. D'où la nécessité de verrouiller également la frontale.

Ce système de gestion des droits des utilisateurs n'offre pas les mêmes protections ni les mêmes possibilités que la sécurité Access présente dans les versions antérieures à 2007. Cependant, il peut répondre à l'essentiel des besoins de verrouillage que l'on rencontre chez les utilisateurs de bases de données Access.

Les fichiersgestion-droits-utilisateurs sont au format accdb :

• le fichier de données « gestion-droits-utilisateurs_data.accdb » à copier sur le serveur ;
• la frontale « gestion-droits-utilisateurs.accdb » à copier sur les postes clients.

Exemples d'exécution de procédures stockées avec ADODBgestion-droits-utilisateurs-adodb pour le paramétrage des formulaires en fonction des droits des utilisateurs :

• le fichier de données « gestion-droits-utilisateurs-adodb_data.accdb » à copier sur le serveur ;
• la frontale « gestion-droits-utilisateurs-adodb.accdb » à copier sur les postes clients.

Bien rétablir les liens au démarrage de l'application en allant chercher le fichier de données côté serveur.

Je tiens à remercier gaby277, Pierre Fauconnier et Laurent Ott de m'avoir conseillé pour la réalisation de cet article, ainsi que Claude Leloup pour sa relecture.