Créer un formulaire Access pour afficher la disponibilité du matériel de location

QteLouee: -[R_DetailLocation].[QteLouee]*([dtCalendrier] Entre [dtDebutLoc] Et [dtFinLoc])

Private Sub MajCalendrier(dtDebut As Date, dtFin As Date)
    ' Met à jour le calendrier en fonction des dates de début et de fin passées en argument
    Dim db As DAO.Database
    Dim rs As DAO.Recordset
    Dim dt As Date
    
    ' référence à la base courante
    Set db = CurrentDb
    
    ' Suppression des données contenues dans la table T_Calendrier
    db.Execute "delete * from T_Calendrier;", dbFailOnError
    
    'Ouverture du recordset basé sur la table T_Calendrier
    Set rs = db.OpenRecordset("T_Calendrier")
    
    dt = dtDebut ' date de début de la période de génération des dates
    
    'Parcours de la période définie par les paramètres de début et de fin passés en argument
    Do While dt <= dtFin
    
        rs.AddNew ' ajout de la date dans la table T_Calendrier
        rs!dtCalendrier = dt
        rs.Update
        
        dt = dt + 1 ' prochain jour
    
    Loop
    ' Libération des variables objet
    rs.Close
    Set rs = Nothing
    Set db = Nothing
End Sub

Public Sub MajPeriodesDispos(dtDebut As Date, dtFin As Date)
    ' Enregistre les périodes et leur quantité en fonction des arguments de la procédure dtdebut et dtfin.
    Dim db As DAO.Database
    Dim qr1 As DAO.QueryDef
    Dim rs1 As DAO.Recordset
    Dim rs2 As DAO.Recordset
    Dim dt1 As Date, dt2 As Date
    Dim idA As Long, qte As Long
    
    ' Met à jour le calendrier en fonction des dates de début et de fin passées en argument
    MajCalendrier dtDebut, dtFin
    
    Set db = CurrentDb
    
    ' Référence à la requête R_MaterielDispoJour
    Set qr1 = db.QueryDefs("R_MaterielDispoJour")
    
    ' Paramétrage de la requête
    qr1.Parameters("[DateMini]").Value = dtDebut
    qr1.Parameters("[DateMaxi]").Value = dtFin
    
    ' Ouverture des recordset de la requête R_MaterielsDisposJour et de la table T_PeriodeDispo
    Set rs1 = qr1.OpenRecordset()
    Set rs2 = db.OpenRecordset("T_PeriodeDispo")
    
    ' Suppression des anciennes périodes enregistrées
    db.Execute "delete * from T_PeriodeDispo;", dbFailOnError
    
    ' Parcours des lignes de la requête R_MaterielsDisposJour
    Do Until rs1.EOF
        
        idA = rs1!IDMateriel
        dt1 = rs1!dtCalendrier: dt2 = rs1!dtCalendrier
        qte = Nz(rs1!qteDispo, 0)
        
        ' Tant que l'id. du Materiel et la quantité est la même, mais aussi que les jours se suivent
        Do While (rs1!IDMateriel = idA) And (dt2 = rs1!dtCalendrier) And (qte = Nz(rs1!qteDispo, 0))
            dt2 = dt2 + 1
            rs1.MoveNext
            If rs1.EOF Then Exit Do ' sortie de la boucle si on est à la fin du recordset
        Loop
        
        ' Création d'un enregistrement dans la table T_PeriodeDispo, pour le matériel et la période identifiés
        rs2.AddNew
        rs2!IDMateriel = idA
        rs2!dtDebutPeriode = dt1
        rs2!dtFinPeriode = (dt2 - 1)
        rs2!qteDispo = qte
        rs2.Update
       
    Loop
    
    ' Libération des variables objet
    
    Set qr1 = Nothing
    
    rs1.Close
    Set rs1 = Nothing
    
    rs2.Close
    Set rs2 = Nothing
    
    Set db = Nothing
End Sub